sábado, 5 de março de 2016

Carregando uma DLL a partir de seus programas Delphi usando Dynamic loading (carregamento dinâmico)

Por carregamento dinâmico (Dynamic loading) entendemos a técnica de carregar e liberar uma DLL (Dynamic Link Library) sempre que quisermos sem a necessidade da criação de uma unit de importação (como fazemos com o carregamento estático).

O processo de carregar uma DLL dinâmicamente envolve os seguintes passos:

a) Devemos declarar uma variável ou tipo procedure ou function que descreve a rotina que queremos chamar na DLL. Se a DLL foi escrita em outra linguagem diferente de Delphi, teremos que traduzir os tipos de dados. Você pode verificar como esta tradução é feita olhando as declarações de importações na unit Windows.pas e comparando com as mesmas funções na API do Windows;

b) Usamos a função LoadLibrary() da API do Windows para carregar a DLL;

c) Efetuamos uma chamada à função GetProcAddress() para obter um ponteiro para o endereço da rotina na DLL;

d) Chamamos a rotina desejada;

e) Chamamos a função FreeLibrary() da API do Windows para liberar a DLL, devolvendo ao sistema a memória alocada durante a sua execução.

Para esta demonstração faremos uso da DLL MinhaDLL.dll, criada em uma das dicas nesta mesma seção.

O primeiro passo é saber a assinatura da função contida na DLL e que pretendemos usar em nosso programa Delphi. A DLL MinhaDLL.dll contém uma função Somar() que recebe dois Integer e retorna a soma como um Integer:

function Somar(a, b: Integer): Integer; stdcall;
begin
  Result := a + b; // retorna a soma
end;

Uma vez que já sabemos a assinatura da função que queremos chamar na DLL, podemos escrever o seguinte código Delphi:

procedure TForm3.Button1Click(Sender: TObject);
type
  // vamos declarar um tipo function
  TSomarFuncao = function(a, b: Integer): Integer; stdcall;
var
  Somar: TSomarFuncao; // uma variável que representará a função
  DLLHandle: THandle; // este é o handle para a DLL
begin
  // vamos carregar a DLL
  DLLHandle := LoadLibrary('MinhaDLL.dll');
  try
    // vamos obter o endereço da função na DLL
    Somar := GetProcAddress(DLLHandle, 'Somar');

    // vamos chamar a função agora
    if Assigned(Somar) then
      ShowMessage(IntToStr(Somar(4, 3)))
    else
      ShowMessage('Não foi possível chamar a rotina desejada');
  finally
    FreeLibrary(DLLHandle); // vamos liberar a DLL
  end;
end;

Note que, no carregamento dinâmico, se a DLL não puder ser encontrada nada acontecerá, a menos que você remova o bloco try...finally do código, o que geraria um erro de acesso à memória. Dentro da IDE do Delphi veríamos a mensagem:

Debugger Exception Notification

Project Project2.exe raised exception class EAccessViolation with
message 'Access violation at address 00000000. Write of address 00000000'.

Fora da IDE a mensagem de erro é bem parecida. Lembre-se de que o os aplicativos procuram as DLLs primeiro no diretório local e em seguida nos diretórios Windows, System e System32.

Nenhum comentário:

Postar um comentário