Como converter uma string em um valor numérico inteiro

*Fonte Arquivo de Códigos

Em algumas situações precisamos converter strings em valores numéricos do tipo inteiro. Isso acontece quando recebemos valores de caixas de texto e precisamos usuá-los em cálculos.

Vamos começar com a função StrToInt() da unit SysUtils. Esta função recebe uma string representando um valor inteiro válido e retorna um valor inteiro. Veja o exemplo:

procedure TForm1.Button1Click(Sender: TObject);

var

  valor1, valor2, soma: Integer;

begin

  // vamos receber as strings dos TEdits e converter

  // seus valores para inteiros

  valor1 := StrToInt(Edit1.Text);

  valor2 := StrToInt(Edit2.Text);

  // vamos obter a soma dos dois valores

  soma := valor1 + valor2;

  // vamos exibir o resultado. Note o uso de IntToStr() para

  // converter o valor inteiro em string

  ShowMessage('A soma é: ' + IntToStr(soma));

end;

Note que, se a string sendo convertida possuir um valor inteiro inválido, uma exceção do tipo EConvertError será lançada. Podemos evitar isso usando a função TryStrToInt(). Esta função recebe dois argumentos: a string a ser convertida e a variável do tipo Integer que receberá o valor. O resultado será true se a conversão for feita com sucesso e false em caso contrário. Veja:

procedure TForm1.Button1Click(Sender: TObject);

var

  valor: Integer;

begin

  // vamos tentar converter o valor da caixa de texto

  // em um inteiro

  if TryStrToInt(Edit1.Text, valor) then

    ShowMessage('Conversão efetuada com sucesso.')

  else

    ShowMessage('Erro na conversão');

end;

Há ainda uma terceira possibilidade: usar a função StrToIntDef(). Esta função funciona exatamente da mesma forma que StrToInt(), exceto que agora, se houver um erro de conversão, um valor inteiro padrão será retornado. Veja:

procedure TForm1.Button1Click(Sender: TObject);

var

  valor: Integer;

begin

  // vamos converter o valor da caixa de texto

  // em um inteiro. Se a conversão não puder ser feita

  // o valor 10 será atribuído à varial valor

  valor := StrToIntDef(Edit1.Text, 10);

  // vamos exibir o resultado

  ShowMessage(IntToStr(valor));

end;

Caso você precise trabalhar com inteiros de 64 bits, poderá usar as funções StrToInt64(), StrToInt64Def() e TryStrToInt64().

Para fins de compatibilidade, esta dica foi escrita usando Delphi 2009.

Aprenda a usar a variável global ShortDateFormat para controlar a formatação de datas

A variável global ShortDateFormat fornece a formatação curta usada, por padrão, na conversão de datas em strings. Esta variável é usada pelas funções DateToStr(), DateTimeToStr() e DateTimeToString(). Os caracteres de formatação usados são:

   y  = Ano com 2 dígitos 

  yy  = Ano com 2 dígitos 

yyyy  = Ano com 4 dígitos 

   m  = Número do mês do ano sem o 0 no início 

  mm  = Número do mês com 2 dígitos 

 mmm  = Mês usando nomes curtos (Jan) 

mmmm  = Mês usando nomes longos  (Janeiro) 

   d  = Número do dia sem o 0 no início 

  dd  = Número do dia com dois dígitos 

 ddd  = Dia usando nomes curtos (Dom) 

dddd  = Dia usando nomes longos  (Domingo) 

Veja o trecho de código abaixo:

procedure TForm1.Button1Click(Sender: TObject);

var

  data: TDateTime;

begin

  // vamos construir a data

  data := StrToDate('13/03/2009');

  // vamos exibir usando a formatação padrão de ShortDateFormat

  showMessage(DateToStr(data));

  // vamos alterar o padrão de formatação de ShortDateFormat

  ShortDateFormat := 'dd ''de'' mmmm ''de'' yyyy';

  // experimente também

  // ShortDateFormat := 'dd/mm/yyyy';

  // vamos exibir usando a nova formatação

  ShowMessage(DateToStr(data));

end;

Como a variável ShortDateFormat é indicada para uso global, é interessante você definir o formato customizado em apenas um lugar de seus códigos, de forma a reaproveitar a formatação nas demais partes de seus programas.

No Windows, a formatação inicial de ShowDateFormat vem de LOCALE_SSHORTDATE, uma constante da API do Windows.

Para fins de compatibilidade, esta dica foi escrita usando Delphi 2009.

Aprenda a usar o tipo de dados WORD da API do Windows em seus programas Delphi

*Fonte Arquivo de Códigos

Em várias ocasiões nós encontramos o tipo de dados WORD em códigos que interagem com a API do Windows. Desta forma, verificando a documentação do Windows descobrimos que este tipo está definido no header WinDef.h da seguinte forma:

typedef unsigned short WORD;

Em C/C++ um short possui 16 bits e o modificador unsigned informa que somente valores positivos são permitidos. Assim, sabemos que o tipo WORD pode guardar 16 bits (ou 2 bytes) de informação. Veja agora como podemos obter os valores máximo e mínimo de um WORD a partir de código Delphi:

procedure TForm3.Button2Click(Sender: TObject);

var

  maximo, minimo: WORD;

begin

  // vamos obter o valor máximo (65.535)

  maximo := High(WORD);

  // vamos obter o valor mínimo (0)

  minimo := Low(WORD);

  // vamos mostrar o resultado

  Memo1.Lines.Add('O valor máximo de um WORD é: ' +

    (IntToStr(maximo)));

  Memo1.Lines.Add('O valor mínimo de um WORD é: ' +

    (IntToStr(minimo)));

end;

Ao executar este código teremos o seguinte resultado:

O valor máximo de um WORD é: 65535

O valor mínimo de um WORD é: 0

Mas, o Delphi também possui um tipo Word. Qual a diferença entre o WORD (da API do Windows) e o Word do Delphi? Não há diferença. O tipo Word também é um inteiro de 16 bits não sinalizado cuja faixa de valores vai de 0 até 65.535. O fato de usarmos WORD em vez de Word em código que interage com a API do Windows é simplesmente para facilitar a tradução do código para outras linguagens que também possuem acesso direto à Win32 API.

Para fins de compatibilidade, esta dica foi escrita usando Delphi 2009.

Algumas funções da API do Windows mostram o tipo de dados LPTSTR. Qual o tipo compatível em Delphi?

*Fonte Arquivo de Códigos

Muitas vezes encontramos funções na API do Windows que possuem parâmetros do tipo LPTSTR. Veja um exemplo:

BOOL GetUserName(

  LPTSTR lpBuffer,

  LPDWORD lpnSize

);

Esta função é usada para obter o nome do usuário atualmente logado no sistema. Note que ela possui dois parâmetros:

lpBuffer - Um ponteiro para um buffer de caracteres que receberá o nome do usuário;

lpnSize - Este parâmetro informa, na entrada, o tamanho do buffer de caracteres e, na saída, informa a quantidade de caracteres copiados para o buffer.

Mas, como podemos usar esta função a partir do Delphi se não temos este tipo de dados (LPTSTR) em Delphi?

Para o tipo LPTSTR nós podemos fornecer uma string terminada em null (#0). E a melhor de forma de se fazer isso é declarando uma matriz de Char. Veja:

procedure TForm1.Button1Click(Sender: TObject);

var

  buffer: array[0..255] of Char; // um buffer de 256 caracteres

  tamanho: DWORD;

begin

  // vamos informar ao Windows o tamanho do buffer

  tamanho := 256;

  // vamos chamar a função da API do Windows

  if GetUserName(buffer, tamanho) then

    begin

      ShowMessage('O nome de usuário é: ' + buffer);

      // informa a quantidade de caracteres usados. Note que

      // o caractere de término da string também é informado

      ShowMessage('A função usou: ' + IntToStr(tamanho) +

        ' caracteres');

    end

  else

    ShowMessage('Não foi possível obter o nome do usuário');

end;

Um cuidado que devemos ter é nunca fornecer um buffer muito pequeno para as funções da API do Windows que esperam um ponteiro para strings do tipo LPTSTR. Experimente, por exemplo, fornecer uma matriz de apenas dois caracteres para a função GetUserName(). A menos que o nome de usuário no seu computador tenha apenas uma letra, a chamada à função falhará.

Em Delphi o tipo PChar é um ponteiro para uma string terminada em null. Podemos usá-la também, mas, neste caso, somos responsáveis por alocar memória para a string usando a procedure GetMem() e liberá-la explicitamente usando FreeMem(). Veja; 

procedure TForm1.Button1Click(Sender: TObject);

var

  buffer: PChar; // um buffer do tipo PChar

  tamanho: DWORD;

begin

  // vamos informar ao Windows o tamanho do buffer

  tamanho := 256;

  // vamos alocar a memória suficiente para receber o nome

  // do usuário

  GetMem(buffer, tamanho);

  // vamos chamar a função da API do Windows

  if GetUserName(buffer, tamanho) then

    begin

      ShowMessage('O nome de usuário é: ' + buffer);

      // informa a quantidade de caracteres usados. Note que

      // o caractere de término da string também é informado

      ShowMessage('A função usou: ' + IntToStr(tamanho) +

        ' caracteres');

    end

  else

    ShowMessage('Não foi possível obter o nome do usuário');

  // vamos liberar o buffer alocado dinamicamente

  FreeMem(buffer);

end;

Finalmente podemos declarar o buffer como String, usar a procedure SetLength() para ajustar seu tamanho e convertê-la para PChar antes de enviá-la à função GetUserName(). Veja como isso pode ser feito:

procedure TForm1.Button1Click(Sender: TObject);

var

  buffer: String; // um buffer que será convertido para PChar

  tamanho: DWORD;

begin

  // vamos informar ao Windows o tamanho do buffer

  tamanho := 256;

  // aqui há um truque interessante. como não vamos precisar

  // de 256 caracteres para guardar o nome de usuário e não podemos

  // correr o risco de enviar uma string muito pequena, a saída

  // é usar o retorno de GetUserName() para ajustar o tamanho

  // da string depois de enviá-la à função.

  // vamos ajustar o tamanho da string

  SetLength(buffer, tamanho);

  GetUserName(PChar(buffer), tamanho);

  // agora tamanho guarda a quantidade de caracteres usados na função

  SetLength(buffer, tamanho);  // comente esta linha para ver o resultado

  // se o valor de tamanho for 0, então a função falhou

  if tamanho > 0 then

    begin

    ShowMessage('O nome de usuário é: ' + buffer);

      // informa a quantidade de caracteres usados. Note que

      // o caractere de término da string também é informado

      ShowMessage('A função usou: ' + IntToStr(tamanho) +

        ' caracteres');

    end

  else

    ShowMessage('Não foi possível obter o nome do usuário');

end;

Para fins de compatibilidade, esta dica foi escrita usando Delphi 2009.

Como salvar uma imagem JPG em um campo BLOB do Firebird (usando dbExpress) e exibí-la de volta em um TImage

Nesta dica mostro como realizar uma tarefa um pouco mais complicada: como salvar uma imagem JPG (o mesmo pode ser feito para Bitmaps e GIFs com pequenas modificações) em um campo BLOB de uma tabela do Firebird (usando dbExpress) e exibí-la de volta em um TImage. O fato de estarmos usando dbExpress complica um pouco mais, visto que não podemos contar com um componente TDBImage para a exibição da imagem recuperada do banco de dados.

Vamos começar criando a tabela no banco de dados Firebird. Para este exemplo usei uma tabela com três campos somente. Veja o comando SQL DDL CREATE TABLE: 

CREATE TABLE PESSOAS (

  ID    INTEGER NOT NULL,

  NOME  VARCHAR(40),

  FOTO  BLOB SUB_TYPE 0 SEGMENT SIZE 80

);

Embora não esteja detalhado, o campo ID é auto-incremento. Tenha a certeza de criar o GENERATOR/SEQUENCE e o trigger necessários. Se estiver com dúvidas em relação a isso, pesquise minhas dicas sobre o assunto.

Uma vez criada a tabela, coloque um componente TSQLConnection (aba dbExpress) no formulário e efetue a conexão com a base de dados Firebird na qual você criou a tabela anterior. Agora coloque um componente TSQLDataSet (também na aba dbExpress) no formulário e ajuste sua propriedade Connection para o componente de conexão. Finalmente, coloque o código abaixo no evento Click de um botão: 

procedure TForm1.Button1Click(Sender: TObject);

var

  nome: string;

  foto: TFileStream;

begin

  if OpenPictureDialog1.Execute then

    begin

      // nome da pessoa

      nome := Edit1.Text;

      // foto da pessoa

      foto := TFileStream.Create(OpenPictureDialog1.FileName, fmOpenRead);

      // vamos definir o comando SQL a ser executado

      SQLDataSet1.CommandText := 'INSERT INTO PESSOAS(NOME, FOTO) VALUES(:nome, :foto)';

      SQLDataSet1.Params[0].Name := 'nome';

      SQLDataSet1.Params[0].Value := nome;

      SQLDataSet1.Params[1].Name := 'foto';

      SQLDataSet1.Params[1].LoadFromStream(foto, ftGraphic);

      // vamos executar o comando

      SQLDataSet1.ExecSQL(False);

      // vamos mostrar uma mensagem indicando o sucesso da operação

      ShowMessage('A imagem foi salva no banco de dados com sucesso.');

   end;

end;

Aqui a imagem JPG será selecionada a partir de um diálogo TOpenPictureDialog. Note também que o nome da pessoa vem de uma caixa de texto TEdit. Execute a aplicação, escolha uma imagem e salve-a na tabela do banco de dados.

A imagem foi salva com sucesso? Hora de exibí-la de volta em um componente TImage. Para isso coloque um componente TImage no formulário e cole o código abaixo no evento Click de um segundo botão: 

procedure TForm1.Button2Click(Sender: TObject);

var

  id: Integer; // id da pessoa

  foto: TStream;  // um stream para o conteúdo do campo BLOB

  imagem: TJPEGImage;  // a imagem JPG

begin

  // uses Jpeg

  // id da pessoa

  id := 1;

  // vamos definir o comando SQL a ser executado

  SQLDataSet1.Close;

  SQLDataSet1.CommandText := 'SELECT * FROM PESSOAS WHERE ID = :id';

  SQLDataSet1.Params[0].Name := 'id';

  SQLDataSet1.Params[0].Value := id;

  // vamos executar o comando

  SQLDataSet1.Open;

  // vamos obter um stream contendo o conteúdo do campo BLOB

  foto := SQLDataSet1.CreateBlobStream(SQLDataSet1.FieldByName('FOTO'), bmRead);

  // vamos criar uma instância de TJPEGImage

  imagem := TJPEGImage.Create;

  // vamos carregar a imagem a partir do stream TStream

  imagem.LoadFromStream(foto);

  // vamos exibir a imagem no Image1

  Image1.Picture.Assign(imagem);

end;

Aqui nós usamos o método CreateBlobStream() da classe TSQLDataSet para criar um stream a partir do campo BLOB da tabela PESSOAS e atribuí-lo à variável foto, do tipo TStream. Em seguida criamos um objeto da classe TJPEGImage, carregamos a imagem JPG a ser exibida a partir do stream foto e finalmente a exibimos no componente TImage. Não se esqueça de adicionar Jpeg á cláusula uses do seu formulário.

Saiba mais sobre o dbExpress e como usar esta arquitetura em suas aplicações Delphi envolvendo banco de dados

*Fonte Arquivo de Código

Uma das características mais significativas do Delphi é seu suporte para os mais diferentes bancos de dados usando diferentes tecnologias de acesso: BDE, dbExpress, InterBase Express, ADO, Borland Data Providers for .NET, etc. Nesta dica abordarei o dbExpress devido à sua forte aceitação no mercado.

Durante as versões iniciais do Delphi houve tentativas de se criar uma API comum para o acesso a vários e diferentes bancos de dados. No entanto, todas as soluções apresentaram um ou mais problemas. Algumas abordagens se tornaram demasiadas complexas, lentas e dificil de distribuir. Outras apresentavam problemas relacionados à complexidade de se escrever os drivers para os bancos de dados, tornando-as limitadas em funcionalidade, lentas e cheias de bugs.

O dbExpress (apresentado pela primeira vez no Delphi 6) supera todos estes problemas ao combinar a abordagem de fornecer uma API comum para vários bancos de dados com a arquitetura provide/resolve da Borland para gerenciar o processo de edição e atualização de dados. 

A arquitetura dbExpress

O dbExpress (anteriormente chamado de DBXpress) foi desenvolvida para atingir os seguintes objetivos:

a) Minimizar o tamanho e uso de recursos do sistema.

b) Maximizar a velocidade.

c) Fornecer suporte cross-platform (independente de plataforma).

d) Fornecer fácil distribuição.

e) Facilitar o desenvolvimento de drivers.

f) Fornecer ao desenvolvedor um maior controle sobre o uso de memória e tráfego de rede.

Os drivers do dbExpress são pequenos e rápidos porque eles fornecem uma funcionalidade muito limitada. Cada driver é implementado como uma DLL única na plataforma Windows e como um único objeto compartilhado na plataforma Linux. Um driver dbExpress implementa cinco interfaces que suportam a obtenção de metadados, a execução de instruções SQL e stored procedures e o retorno de um cursor unidirecional somente leitura para um conjunto de resultados (result set). Contudo, quando usado em conjunto com os componentes DataSetProvider e ClientDataSet para implementar a estratégia de acesso de dados provide/resolve, o dbExpress nos oferede um sistema completo de alta concorrência e de alta performance para o desenvolvimento de aplicações que lidam com bancos de dados SQL.

Os componentes do dbExpress são:

TSQLConnection - Define uma conexão com um banco de dados, similar ao TDatabase.

TSQLDataSet - Representa um conjunto de dados unidirecional de propósito geral que executa a instrução SQL definida na propriedade CommandText. O valor desta propriedade pode ser uma instrução SELECT que retorna um conjunto de dados, uma instrução SQL que não retorna dados ou executa uma stored procedure.

TSQLQuery - Suporta instruções SQL a serem executadas e que retornam um conjunto de dados unidirecional ou atualizam dados ou esquemas de banco de dados.

TSQLStoredProc - Executa uma stored procedure. Se houver um conjunto de dados como retorno este será unidirecional.

TSQLTable - Fornece acesso unidirecional a uma tabela da base de dados.

TSQLMonitor - Usado para interceptar e exibir mensagens transferidas entre um TSQLConnection e o banco de dados.

TSimpleClientDataSet - Combina um TSQLDataSet e TDataSetProvider em um mesmo componente para suportar dados em cache de memória.

Como obter uma substring de uma string

*Fonte Arquivo de Códigos

Em algumas situações precisamos obter uma substring de uma string. Em Delphi isso pode ser feito por meio da função AnsiMidStr(). Esta função requer a string a partir da qual a substring será obtida, a posição inicial da substring (começando em 1) e a quantidade de caracteres que comporâo a substring. O retorno será uma nova string contendo a substring obtida. Veja o exemplo:

procedure TForm1.Button1Click(Sender: TObject);

var

  frase, substring: string;

begin

  frase := 'Programar em Delphi é muito bom';

  // vamos obter a substring "Delphi"

  substring := AnsiMidStr(frase, 14, 6);

  // vamos exibir o resultado

  ShowMessage('Resultado: ' + substring);

end;

Não se esqueça de adicionar a unit StrUtils no uses do seu formulário.

Para questões de compatibilidade, esta dica foi escrita usando Delphi 2009.